RECHERCHEX dans Excel : syntaxe, exemples et exercices corrigés
Mis à jour le
RECHERCHEX cherche une valeur dans une plage et renvoie l’élément correspondant d’une autre plage. Par exemple, =RECHERCHEX(F2;A2:A9;D2:D9) trouve le numéro de commande de F2 et renvoie son montant (colonne D). Elle fait une correspondance exacte par défaut, peut chercher vers la gauche et afficher votre propre texte au lieu de #N/A.
Syntaxe de RECHERCHEX
=RECHERCHEX(valeur_cherchée; tableau_recherche; tableau_renvoyé; [si_non_trouvé]; [mode_correspondance]; [mode_recherche])
- valeur_cherchée
- La valeur à trouver, par exemple un numéro de commande ou la cellule qui le contient.
- tableau_recherche
- La colonne (ou la ligne) où chercher, par exemple
A2:A9. - tableau_renvoyé
- La plage d’où renvoyer le résultat, par exemple
D2:D9. Elle doit avoir autant de lignes que tableau_recherche et peut être à gauche ou à droite. Sélectionnez plusieurs colonnes pour toutes les renvoyer. - si_non_trouvé
- Facultatif. Ce qui s’affiche si rien ne correspond, par exemple
"Introuvable". Sans lui, RECHERCHEX renvoie #N/A. - mode_correspondance
- Facultatif.
0correspondance exacte (par défaut),-1exacte ou valeur inférieure suivante,1exacte ou valeur supérieure suivante,2caractères génériques (* et ?). - mode_recherche
- Facultatif.
1cherche à partir du premier élément (par défaut),-1à partir du dernier, pour trouver la correspondance la plus récente.
Exercices RECHERCHEX à faire ici
Tapez votre formule directement dans la feuille. Elle est vérifiée comme dans Excel, avec des points-virgules ou des virgules, en français ou en anglais.
Trouver le montant d’une commande
En F2, écrivez une RECHERCHEX qui renvoie le montant de la commande 5024, à partir des commandes A1:D9.
| N° commande | Client | Ville | Montant (€) | Montant de la commande 5024 (€) | |
| 5031 | Café des Arts | Lyon | 412,50 | ||
| 5007 | Librairie du Port | Nantes | 86,00 | ||
| 5024 | Cabinet Lemoine | Lille | 1 290,00 | ||
| 5012 | Salle Altitude | Bordeaux | 245,00 | ||
| 5040 | Boulangerie Martin | Rennes | 37,90 | ||
| 5019 | Épicerie du Marché | Toulouse | 768,00 | ||
| 5003 | Garage des Quais | Nice | 159,00 | ||
| 5028 | Fleurs & Co | Dijon | 532,00 |
Comment utiliser RECHERCHEX, étape par étape
- Cliquez sur la cellule du résultat et tapez
=RECHERCHEX(. - Cliquez sur la cellule qui contient la valeur cherchée, puis tapez un point-virgule.
- Sélectionnez la colonne où chercher, tapez un point-virgule, puis sélectionnez la colonne à renvoyer. Appuyez sur F4 sur chaque plage pour la figer avec $ si vous allez recopier la formule.
- Fermez la parenthèse et validez avec Entrée. Ajoutez un 4e argument entre guillemets pour afficher un message au lieu de #N/A.
Exemples de RECHERCHEX
Montant à partir d’un numéro de commande
=RECHERCHEX(F2;$A$2:$A$9;$D$2:$D$9)
Renvoie le montant de la commande saisie en F2. Ni numéro de colonne, ni FAUX.
Chercher vers la gauche
=RECHERCHEX(F2;$B$2:$B$9;$A$2:$A$9)
Cherche le client dans la colonne B et renvoie le numéro de commande de la colonne A, à gauche.
Afficher un message au lieu de #N/A
=RECHERCHEX(F2;$A$2:$A$9;$D$2:$D$9;"Introuvable")
Le 4e argument remplace #N/A quand la commande n’existe pas.
Commission par tranche de CA
=RECHERCHEX(D2;$A$2:$A$6;$B$2:$B$6;;-1)
Avec mode_correspondance -1, RECHERCHEX renvoie la plus grande tranche inférieure ou égale à D2. Les deux points-virgules sautent si_non_trouvé.
Erreurs fréquentes et solutions
| Résultat | Cause | Solution |
|---|---|---|
| #N/A | La valeur n’est pas dans tableau_recherche : faute de frappe, espaces en trop ou nombre stocké en texte. Ou les plages ont bougé en recopiant la formule. | Vérifiez la valeur, utilisez SUPPRESPACE, figez les plages avec $ ou ajoutez l’argument si_non_trouvé. |
| #VALEUR! | tableau_recherche et tableau_renvoyé n’ont pas le même nombre de lignes, par exemple A2:A9 et D2:D8. | Faites commencer et finir les deux plages sur les mêmes lignes. |
| #NOM? | Votre version d’Excel n’a pas RECHERCHEX (Excel 2019 et versions antérieures), le nom est mal orthographié, ou la formule a été copiée avec des virgules depuis un site anglais. | Utilisez Excel 2021, 2024 ou Microsoft 365, vérifiez le nom et le point-virgule, ou revenez à RECHERCHEV ou INDEX + EQUIV. |
| #PROPAGATION! | tableau_renvoyé contient plusieurs colonnes et les cellules où les résultats doivent s’afficher ne sont pas vides. | Videz les cellules à droite de la formule ou renvoyez une seule colonne. |
RECHERCHEX ou RECHERCHEV ?
RECHERCHEX remplace la plupart des RECHERCHEV : vous sélectionnez la colonne à renvoyer au lieu de compter son numéro, la correspondance exacte est le mode par défaut, elle cherche vers la gauche et l’insertion d’une colonne ne la casse pas. RECHERCHEV fonctionne dans toutes les versions d’Excel, y compris 2019 et antérieures où RECHERCHEX renvoie #NOM?, et vous la croiserez encore dans les fichiers partagés.
Questions fréquentes
Quelle différence entre RECHERCHEX et RECHERCHEV ?
RECHERCHEV a besoin d’un numéro de colonne, cherche uniquement dans la première colonne et renvoie des colonnes situées à sa droite. RECHERCHEX reçoit des plages de recherche et de résultat séparées : elle cherche vers la gauche, en correspondance exacte par défaut.
Pourquoi RECHERCHEX affiche #NOM? ?
RECHERCHEX existe uniquement dans Excel 2021, Excel 2024, Microsoft 365 et Excel pour le web. Dans Excel 2019 ou avant, le nom n’est pas reconnu. Vérifiez aussi l’orthographe.
Comment trouver la dernière correspondance avec RECHERCHEX ?
Mettez mode_recherche à -1 pour chercher à partir du bas : =RECHERCHEX(F2;A2:A9;D2:D9;;0;-1).
RECHERCHEX peut-elle renvoyer plusieurs colonnes ?
Oui. Sélectionnez plusieurs colonnes comme tableau_renvoyé, par exemple B2:D9, et les résultats se propagent dans les cellules de droite.
Continuez à pratiquer
Les 10 exercices RECHERCHEX, avec explications et suivi de progression.
Ouvrir les exercices RECHERCHEX