BUSCARX en Excel
Actualizado el
BUSCARX busca un valor en un rango y devuelve el elemento correspondiente de otro rango. Por ejemplo, =BUSCARX(F2;A2:A9;D2:D9) encuentra el número de pedido de F2 y devuelve su importe de la columna D. Usa coincidencia exacta por defecto, busca hacia la izquierda y puede mostrar tu propio texto en lugar de #N/A. Si tu Excel usa comas, escribe =BUSCARX(F2,A2:A9,D2:D9).
Sintaxis de BUSCARX
=BUSCARX(valor_buscado; matriz_buscada; matriz_devuelta; [si_no_se_encuentra]; [modo_de_coincidencia]; [modo_de_búsqueda])
- valor_buscado
- El valor que buscas, como un número de pedido o la celda que lo contiene.
- matriz_buscada
- La columna (o fila) donde buscar, por ejemplo
A2:A9. - matriz_devuelta
- El rango del que sale el resultado, por ejemplo
D2:D9. Debe tener tantas filas como matriz_buscada y puede estar a la izquierda o a la derecha. Selecciona varias columnas para devolverlas todas a la vez. - si_no_se_encuentra
- Opcional. Lo que se muestra cuando no hay coincidencia, por ejemplo
"No encontrado". Sin él, BUSCARX devuelve #N/A. - modo_de_coincidencia
- Opcional.
0coincidencia exacta (predeterminado),-1exacta o el siguiente elemento menor,1exacta o el siguiente elemento mayor,2comodines (* y ?). - modo_de_búsqueda
- Opcional.
1busca desde el primer elemento (predeterminado),-1desde el último, para encontrar la coincidencia más reciente.
Practica BUSCARX aquí
Escribe tu fórmula directamente en la hoja. Se revisa como en Excel, con punto y coma o con coma, en español o en inglés.
Encontrar el importe de un pedido
En F2, escribe un BUSCARX que devuelva el importe del pedido 5024, usando los pedidos de A1:D9.
| No. pedido | Cliente | Ciudad | Importe ($) | Importe del pedido 5024 ($) | |
| 5031 | Café La Esquina | Monterrey | 412,50 | ||
| 5007 | Librería El Puerto | Puebla | 86,00 | ||
| 5024 | Consultorio Dental Ruiz | Guadalajara | 1290,00 | ||
| 5012 | Gimnasio Cumbre | Querétaro | 245,00 | ||
| 5040 | Panadería San José | Mérida | 37,90 | ||
| 5019 | Abarrotes Doña Lupe | León | 768,00 | ||
| 5003 | Taller Mecánico Ríos | Toluca | 159,00 | ||
| 5028 | Florería Jazmín | Morelia | 532,00 |
Cómo usar BUSCARX paso a paso
- Haz clic en la celda del resultado y escribe
=BUSCARX(. - Haz clic en la celda con el valor buscado y escribe el separador (
;o,según tu Excel). - Selecciona la columna donde buscar, escribe el separador y selecciona la columna que quieres devolver. Presiona F4 en cada rango para fijarlo con $ si vas a copiar la fórmula.
- Cierra el paréntesis y presiona Enter. Agrega un 4.º argumento entre comillas si quieres un mensaje en lugar de #N/A.
Ejemplos de BUSCARX
Importe a partir del número de pedido
=BUSCARX(F2;$A$2:$A$9;$D$2:$D$9)
Devuelve el importe del pedido de F2. Sin número de columna y sin FALSO.
Buscar hacia la izquierda
=BUSCARX(F2;$B$2:$B$9;$A$2:$A$9)
Busca el cliente en la columna B y devuelve el número de pedido de la columna A, a la izquierda.
Mostrar un mensaje en lugar de #N/A
=BUSCARX(F2;$A$2:$A$9;$D$2:$D$9;"No encontrado")
El 4.º argumento reemplaza #N/A cuando el pedido no existe.
Comisión por rango de ventas
=BUSCARX(D2;$A$2:$A$6;$B$2:$B$6;;-1)
Con modo_de_coincidencia -1, BUSCARX devuelve el mayor rango menor o igual a D2. Los dos separadores seguidos omiten si_no_se_encuentra.
Errores comunes de BUSCARX y cómo resolverlos
| Resultado | Causa | Solución |
|---|---|---|
| #N/A | El valor no está en matriz_buscada: un error de escritura, espacios o un número guardado como texto. O los rangos se movieron al copiar la fórmula. | Revisa el valor, usa ESPACIOS, fija los rangos con $ o agrega si_no_se_encuentra. |
| #¡VALOR! | matriz_buscada y matriz_devuelta no tienen el mismo número de filas, por ejemplo A2:A9 y D2:D8. | Haz que los dos rangos empiecen y terminen en las mismas filas. |
| #¿NOMBRE? | Tu versión de Excel no tiene BUSCARX (Excel 2019 y anteriores) o el nombre está mal escrito. | Usa Excel 2021, 2024 o Microsoft 365, revisa el nombre, o vuelve a BUSCARV o INDICE y COINCIDIR. |
| #¡DESBORDAMIENTO! | matriz_devuelta tiene varias columnas y las celdas donde se desbordan los resultados no están vacías. | Vacía las celdas a la derecha de la fórmula o devuelve una sola columna. |
BUSCARX o BUSCARV
BUSCARX sustituye a la mayoría de los BUSCARV: seleccionas la columna que quieres devolver en lugar de contar su número, la coincidencia exacta viene por defecto, busca hacia la izquierda y no se rompe al insertar columnas. BUSCARV funciona en todas las versiones de Excel, incluidas 2019 y anteriores, donde BUSCARX da #¿NOMBRE?, así que lo seguirás encontrando en archivos compartidos.
Preguntas frecuentes
¿Qué diferencia hay entre BUSCARX y BUSCARV?
BUSCARV necesita un número de columna, busca solo en la primera columna y devuelve columnas a su derecha. BUSCARX recibe por separado el rango de búsqueda y el de resultado, así que busca hacia la izquierda y usa coincidencia exacta por defecto.
¿Por qué BUSCARX da #¿NOMBRE??
BUSCARX solo existe en Excel 2021, Excel 2024, Microsoft 365 y Excel para la Web. En Excel 2019 o anterior, el nombre no se reconoce. Revisa también cómo está escrito.
¿Cómo encuentro la última coincidencia con BUSCARX?
Pon modo_de_búsqueda en -1 para buscar de abajo hacia arriba: =BUSCARX(F2;A2:A9;D2:D9;;0;-1).
¿BUSCARX puede devolver varias columnas?
Sí. Selecciona varias columnas como matriz_devuelta, por ejemplo B2:D9, y los resultados se desbordan en las celdas de la derecha.
Sigue practicando
Los 10 ejercicios de BUSCARX, con explicaciones y seguimiento de tu avance.
Abrir los ejercicios de BUSCARX