RECHERCHEV dans Excel : syntaxe, exemples et exercices corrigés
Mis à jour le
RECHERCHEV cherche une valeur dans la première colonne d’un tableau et renvoie la valeur d’une autre colonne sur la même ligne. Par exemple, =RECHERCHEV(E2;A2:C9;3;FAUX) trouve le code produit de E2 et renvoie son prix (3e colonne). Mettez FAUX pour une correspondance exacte.
Syntaxe de RECHERCHEV
=RECHERCHEV(valeur_cherchée; table_matrice; no_index_col; [valeur_proche])
- valeur_cherchée
- La valeur à trouver, par exemple un code produit. Elle doit se trouver dans la première colonne du tableau.
- table_matrice
- Le tableau où chercher, par exemple
A2:C9. Figez-le avec$($A$2:$C$9) avant de recopier la formule. - no_index_col
- Le numéro de la colonne à renvoyer : 1 est la première colonne de la plage, pas la colonne A.
- valeur_proche
FAUX(ou 0) pour une correspondance exacte.VRAI(ou omis) pour une correspondance approximative sur une première colonne triée, utile pour des tranches.
Exercices RECHERCHEV à faire ici
Tapez votre formule directement dans la feuille. Elle est vérifiée comme dans Excel, avec des points-virgules ou des virgules, en français ou en anglais.
Trouver le prix d’un produit
En F2, écrivez une RECHERCHEV qui renvoie le prix du code saisi en E2, à partir du tableau A1:C9.
| Code | Produit | Prix (€) | Code | Prix (€) | |
| P-101 | Souris sans fil | 24,90 | P-104 | ||
| P-102 | Câble USB-C | 9,50 | |||
| P-103 | Clavier | 49,00 | |||
| P-104 | Écran 24" | 189,00 | |||
| P-105 | Support PC portable | 35,00 | |||
| P-106 | Webcam HD | 59,90 | |||
| P-107 | Casque | 79,00 | |||
| P-108 | Lampe de bureau | 32,50 |
Comment faire une RECHERCHEV, étape par étape
- Cliquez sur la cellule du résultat et tapez
=RECHERCHEV(. - Cliquez sur la cellule qui contient la valeur cherchée, puis tapez un point-virgule.
- Sélectionnez le tableau, en commençant par la colonne qui contient la valeur cherchée. Appuyez sur F4 pour le figer avec $.
- Tapez le numéro de colonne, un point-virgule, puis
FAUX, et validez avec Entrée.
Exemples de RECHERCHEV
Prix à partir d’un code produit
=RECHERCHEV(E2;$A$2:$C$9;3;FAUX)
Renvoie le prix du code saisi en E2.
Chercher dans une autre feuille
=RECHERCHEV(A2;Produits!$A:$C;3;FAUX)
Le tableau peut être sur une autre feuille : faites précéder la plage du nom de la feuille et d’un point d’exclamation.
Commission par tranche de CA
=RECHERCHEV(D2;$A$2:$B$6;2;VRAI)
Avec VRAI, RECHERCHEV renvoie la plus grande tranche inférieure ou égale à D2. La première colonne doit être triée par ordre croissant.
Afficher un message au lieu de #N/A
=SIERREUR(RECHERCHEV(E2;$A$2:$C$9;3;FAUX);"Introuvable")
SIERREUR remplace toute erreur par votre propre texte.
Erreurs fréquentes et solutions
| Résultat | Cause | Solution |
|---|---|---|
| #N/A | La valeur n’est pas dans la première colonne, contient des espaces, ou est un nombre stocké en texte. Ou la plage a bougé en recopiant la formule. | Vérifiez la valeur, utilisez SUPPRESPACE, convertissez le texte en nombre et figez la plage avec $. |
| #REF! | no_index_col dépasse le nombre de colonnes du tableau. | Élargissez la plage ou réduisez le numéro de colonne. |
| #VALEUR! | no_index_col est inférieur à 1. | Utilisez un numéro de colonne de 1 ou plus. |
| #NOM? | Formule copiée d’un site anglais (VLOOKUP, FALSE) ou séparateur « , » au lieu de « ; ». | Utilisez les noms français et le point-virgule. |
| Mauvaise valeur, sans erreur | valeur_proche omis ou VRAI sur un tableau non trié. | Ajoutez FAUX comme dernier argument. |
RECHERCHEV ou RECHERCHEX ?
RECHERCHEX (Excel 2021 et Microsoft 365) peut chercher vers la gauche, fait une correspondance exacte par défaut et ne casse pas quand on insère une colonne. RECHERCHEV fonctionne dans toutes les versions et dans la plupart des fichiers que vous recevrez au travail : il faut connaître les deux.
Questions fréquentes
Pourquoi ma RECHERCHEV renvoie #N/A ?
La valeur cherchée est introuvable dans la première colonne. Causes habituelles : espaces en trop, nombres stockés en texte, ou plage décalée en recopiant la formule. Figez-la avec $.
RECHERCHEV peut-elle chercher à gauche ?
Non. RECHERCHEV ne renvoie que des colonnes à droite de la colonne de recherche. Utilisez RECHERCHEX ou INDEX + EQUIV pour chercher à gauche.
Que veut dire FAUX dans RECHERCHEV ?
FAUX demande une correspondance exacte. Sans lui, RECHERCHEV fait une correspondance approximative et peut renvoyer une mauvaise ligne sans erreur.
Comment faire une RECHERCHEV entre deux feuilles ?
Ajoutez le nom de la feuille avant la plage : =RECHERCHEV(A2;Feuil2!$A:$C;3;FAUX).
Continuez à pratiquer
Les 10 exercices RECHERCHEV, avec explications et suivi de progression.
Ouvrir les exercices RECHERCHEV