Fonctions JOINDRE.TEXTE et CONCAT dans Excel
Mis à jour le
JOINDRE.TEXTE assemble des textes et des plages entières avec le même délimiteur entre chaque morceau, et peut ignorer les cellules vides : =JOINDRE.TEXTE(", ";VRAI;B2:D2) renvoie Français, Anglais. CONCAT joint des plages sans rien entre elles : =CONCAT(A2:C2) transforme B, 12 et C en B12C.
Syntaxe de JOINDRE.TEXTE et CONCAT
=JOINDRE.TEXTE(délimiteur; ignorer_vide; texte1; [texte2]; …) =CONCAT(texte1; [texte2]; …)
- délimiteur
- Le texte placé entre les morceaux, entre guillemets :
", "," "ou"; ".""pour aucun. - ignorer_vide
- VRAI ignore les cellules vides, pour ne jamais avoir deux délimiteurs à la suite. FAUX les garde.
- texte1
- Le premier morceau : une plage comme
B2:D2, une cellule ou un texte entre guillemets. Les deux fonctions acceptent des plages. - texte2; …
- Facultatif. D’autres morceaux, joints dans l’ordre. JOINDRE.TEXTE en accepte jusqu’à 252, CONCAT jusqu’à 253.
Exercices JOINDRE.TEXTE et CONCAT à faire ici
Tapez votre formule directement dans la feuille. Elle est vérifiée comme dans Excel, avec des points-virgules ou des virgules, en français ou en anglais.
Joindre une ligne avec des virgules
Chaque personne indique jusqu’à trois langues en B:D. En E2, utilisez JOINDRE.TEXTE pour lister les langues de la ligne 2 séparées par une virgule et une espace, en ignorant les cellules vides, puis recopiez jusqu’en E5.
| Nom | Langue 1 | Langue 2 | Langue 3 | Langues |
| Camille Martin | Français | Anglais | ||
| Lucas Bernard | Espagnol | |||
| Léa Dubois | Allemand | Français | Italien | |
| Hugo Thomas | Portugais | Français |
Joindre une plage, étape par étape
- Cliquez sur la cellule du résultat et tapez
=JOINDRE.TEXTE(. - Tapez le délimiteur entre guillemets, par exemple
", ", puis un point-virgule. - Tapez VRAI pour ignorer les vides, un point-virgule, puis sélectionnez la plage à joindre, par exemple
B2:D2. - Fermez la parenthèse et validez. Sans délimiteur du tout,
=CONCAT(B2:D2)est plus court.
Exemples avec JOINDRE.TEXTE et CONCAT
Une liste avec des virgules
=JOINDRE.TEXTE(", ";VRAI;B2:D2)
Renvoie Français, Anglais quand D2 est vide. Sans VRAI, on obtiendrait Français, Anglais, avec une virgule à la fin.
Nom complet avec deuxième prénom facultatif
=JOINDRE.TEXTE(" ";VRAI;A2:C2)
Renvoie Camille Marie Martin, et Lucas Bernard avec une seule espace quand il n’y a pas de deuxième prénom.
Un code à partir de trois colonnes
=CONCAT(A2:C2)
Renvoie B12C à partir de l’allée B, du rayon 12 et du niveau C. CONCAT prend la plage d’un coup, sans délimiteur.
Une colonne dans une seule cellule
=JOINDRE.TEXTE("; ";VRAI;A2:A8)
Réunit les adresses e-mail d’une colonne en une liste de destinataires, en sautant les lignes vides.
Erreurs fréquentes et solutions
| Résultat | Cause | Solution |
|---|---|---|
| Délimiteurs en double | ignorer_vide vaut FAUX : chaque cellule vide garde son délimiteur, d’où Français, , Anglais. | Mettez VRAI en deuxième argument : =JOINDRE.TEXTE(", ";VRAI;B2:D2). |
| Mots collés | CONCAT n’ajoute rien entre les cellules : Camille et Martin deviennent CamilleMartin. | Utilisez JOINDRE.TEXTE avec un délimiteur, =JOINDRE.TEXTE(" ";VRAI;A2:B2), ou ajoutez " " comme argument dans CONCAT. |
| Une date devient un nombre | La jointure utilise la valeur de la cellule, pas son format : une date s’affiche comme un nombre, par exemple 45658. | Formatez-la dans la formule avec TEXTE, par exemple TEXTE(B2;"jj/mm/aaaa"). |
| #NOM? | JOINDRE.TEXTE et CONCAT demandent Excel 2019 ou Microsoft 365. Les versions antérieures ne les connaissent pas. | Dans une ancienne version, utilisez CONCATENER ou l’opérateur &, cellule par cellule. |
JOINDRE.TEXTE, CONCAT ou CONCATENER ?
CONCATENER et l’opérateur &, vus dans la leçon sur CONCATENER, joignent des morceaux cités un par un. CONCAT est leur remplaçant moderne : même travail, mais il accepte aussi une plage comme A2:C2. JOINDRE.TEXTE va plus loin et place le même délimiteur entre chaque morceau, ce qu’il faut pour des listes, des noms et des adresses. CONCATENER fonctionne toujours dans toutes les versions : gardez-le pour les fichiers qui doivent s’ouvrir dans Excel 2016 ou plus ancien.
Questions fréquentes
Quelle différence entre CONCAT et CONCATENER ?
CONCAT accepte des plages entières, CONCATENER demande chaque cellule séparément. Sinon le résultat est le même, et CONCATENER reste disponible pour la compatibilité avec les anciens fichiers.
Comment joindre des cellules avec un retour à la ligne ?
Utilisez CAR(10) comme délimiteur, =JOINDRE.TEXTE(CAR(10);VRAI;A2:A5), et activez Renvoyer à la ligne automatiquement sur la cellule pour voir les lignes.
JOINDRE.TEXTE peut-il ignorer les cellules vides ?
Oui, c’est son deuxième argument. VRAI les ignore, FAUX garde un délimiteur pour chaque cellule vide.
Y a-t-il une limite de longueur ?
Une cellule contient au plus 32 767 caractères. Si le texte joint est plus long, JOINDRE.TEXTE renvoie #VALEUR!.
Continuer à vous entraîner
Les 5 exercices JOINDRE.TEXTE et CONCAT, avec explications et suivi de progression.
Ouvrir les exercices JOINDRE.TEXTE