Fonctions ET et OU dans Excel : plusieurs conditions dans un SI
Mis à jour le
ET renvoie VRAI quand toutes ses conditions sont vraies ; OU renvoie VRAI dès qu’une seule l’est. Elles servent surtout de test à SI : =SI(ET(B2>15000;C2>=4);250;0) verse une prime de 250 seulement si le CA dépasse 15 000 € et que la note est d’au moins 4.
Syntaxe des fonctions ET et OU
=ET(valeur_logique1; [valeur_logique2]; …) =OU(valeur_logique1; [valeur_logique2]; …)
- valeur_logique1
- La première condition, le plus souvent une comparaison comme
B2>15000ouC2="Oui". - valeur_logique2, …
- Les autres conditions, séparées par des points-virgules. ET les veut toutes VRAI, OU n’en demande qu’une. Jusqu’à 255.
Exercices ET et OU à faire ici
Tapez votre formule directement dans la feuille. Elle est vérifiée comme dans Excel, avec des points-virgules ou des virgules, en français ou en anglais.
Payée et expédiée
Une commande peut être clôturée quand elle est payée et expédiée. En D2, écrivez un ET qui renvoie VRAI quand B2 et C2 valent tous les deux Oui, puis recopiez-le jusqu’en D6.
| Commande | Payée | Expédiée | À clôturer |
| SO-1041 | Oui | Non | |
| SO-1042 | Oui | Oui | |
| SO-1043 | Non | Oui | |
| SO-1044 | Oui | Oui | |
| SO-1045 | Non | Non |
Comment combiner des conditions, étape par étape
- Écrivez d’abord chaque condition seule, par exemple
B2>15000etC2>=4. - Placez-les dans
ET(si toutes doivent être vraies, ou dansOU(si une seule suffit, séparées par un point-virgule. - Validez avec Entrée pour voir VRAI ou FAUX, et vérifiez quelques lignes à la main.
- Pour afficher votre propre résultat, utilisez ce ET ou ce OU comme premier argument d’un SI :
=SI(ET(…);250;0).
Exemples avec ET et OU
Payée et expédiée
=ET(B2="Oui";C2="Oui")
VRAI seulement si les deux cellules valent Oui. Un seul Non donne FAUX.
Livraison offerte
=OU(B2>=50;C2="Oui")
VRAI si la commande atteint 50 € ou si le client est adhérent.
Signaler un projet à risque
=SI(OU(B2>0;D2>C2);"À revoir";"Conforme")
Affiche À revoir quand le projet est en retard ou hors budget.
OU dans ET
=SI(ET(OU(B2>=2;C2="Oui");D2=0);"30 jours";"Prépaiement")
Deux ans d’ancienneté ou un garant, et aucun impayé : le OU est l’une des conditions du ET.
Erreurs fréquentes et solutions
| Résultat | Cause | Solution |
|---|---|---|
| Toujours FAUX | ET utilisé alors qu’une condition suffit, ou une plage comme B2:B6>0 au lieu d’une cellule : ET exige alors que toutes les lignes de la plage passent le test. | Utilisez OU quand une condition suffit, et testez une ligne à la fois : B2>0. |
| #VALEUR! | Les arguments sont des cellules texte et non des comparaisons, par exemple =ET(A2;B2) avec des noms dans les deux cellules. ET ignore le texte et, sans rien à tester, renvoie #VALEUR!. | Écrivez une comparaison complète pour chaque argument : A2="Oui". |
| Mauvais résultat pile au seuil | > et >= confondus : une valeur égale au seuil tombe du mauvais côté. | Relisez la règle : « supérieur à » s’écrit >, « au moins » s’écrit >=. |
| #NOM? | Un texte sans guillemets, comme C2=Oui, ou une formule anglaise copiée telle quelle (AND, OR). | Mettez le texte entre guillemets, C2="Oui", et utilisez ET et OU. |
ET, OU, NON ou SI imbriqués ?
ET et OU ne remplacent pas des SI imbriqués. Les SI imbriqués choisissent un résultat parmi plusieurs tranches, alors que ET et OU combinent des conditions en un seul VRAI ou FAUX pour une décision. Pour « ne pas », entourez la condition de NON : =ET(B2>0;NON(C2="Clos")). Pour compter ou additionner des lignes, NB.SI.ENS et SOMME.SI.ENS combinent déjà leurs critères comme un ET.
Questions fréquentes
Comment faire un SI avec deux conditions ?
Mettez les deux conditions dans ET (toutes vraies) ou OU (une seule suffit) et utilisez-le comme test : =SI(ET(B2>15000;C2>=4);250;0).
Peut-on combiner ET et OU ?
Oui, en imbriquant l’un dans l’autre. =ET(OU(B2>=2;C2="Oui");D2=0) signifie « B2 au moins 2 ou C2 vaut Oui, et D2 vaut 0 ».
ET et OU tiennent-ils compte des majuscules ?
Non. C2="oui" est VRAI pour Oui, OUI ou oui.
Combien de conditions peut-on mettre dans ET ?
Jusqu’à 255. Au-delà de trois ou quatre, une colonne intermédiaire par condition garde la formule lisible.
Continuer à vous entraîner
Les 5 exercices ET et OU, avec explications et suivi de progression.
Ouvrir les exercices ET et OU