NB.SI dans Excel : compter les cellules selon un critère
Mis à jour le
NB.SI compte les cellules d’une plage qui remplissent une condition. Par exemple, =NB.SI(C2:C9;"Livrée") compte combien de commandes de C2:C9 ont le statut Livrée. La condition peut être un texte, une comparaison comme ">500" ou une référence de cellule.
Syntaxe de NB.SI
=NB.SI(plage; critère)
- plage
- Les cellules à examiner, par exemple
C2:C9. Figez-la avec$($C$2:$C$9) avant de recopier la formule. - critère
- La condition à remplir pour être comptée : un texte entre guillemets (
"Livrée"), une comparaison entre guillemets (">500","<>") ou une référence de cellule (F2). Les majuscules ne comptent pas.
Exercices NB.SI à faire ici
Tapez votre formule directement dans la feuille. Elle est vérifiée comme dans Excel, avec des points-virgules ou des virgules, en français ou en anglais.
Compter les commandes d’un statut
En F2, utilisez NB.SI pour compter combien de commandes de C2:C9 ont le statut Livrée.
| N° commande | Commercial | Statut | Montant (€) | Commandes livrées | |
| C-2401 | Camille | Livrée | 320,00 | ||
| C-2402 | Lucas | En attente | 780,00 | ||
| C-2403 | Camille | Livrée | 145,00 | ||
| C-2404 | Léa | Annulée | 1 250,00 | ||
| C-2405 | Lucas | Livrée | 560,00 | ||
| C-2406 | Camille | En attente | 90,00 | ||
| C-2407 | Léa | Livrée | 430,00 | ||
| C-2408 | Lucas | Annulée | 615,00 |
Comment utiliser NB.SI, étape par étape
- Cliquez sur la cellule du résultat et tapez
=NB.SI(. - Sélectionnez la plage à examiner, puis tapez un point-virgule. Appuyez sur F4 pour la figer avec $ si vous allez recopier la formule.
- Tapez la condition : un texte ou une comparaison entre guillemets, ou cliquez sur la cellule qui la contient.
- Fermez la parenthèse et validez avec Entrée.
Exemples de NB.SI
Compter un texte
=NB.SI(C2:C9;"Livrée")
Compte les cellules de C2:C9 qui contiennent exactement Livrée, en majuscules ou non.
Compter les valeurs au-dessus d’un nombre
=NB.SI(D2:D9;">50")
Compte les valeurs supérieures à 50. Mettez ">=50" pour inclure 50, "<50" pour les valeurs en dessous.
Prendre la condition dans une cellule
=NB.SI($B$2:$B$9;F2)
Compte les cellules égales à F2. Pour combiner une comparaison et une cellule, reliez-les avec & : =NB.SI(D2:D9;">"&F2).
Compter les cellules non vides
=NB.SI(A2:A100;"<>")
"<>" signifie « différent de rien » : la formule compte toutes les cellules qui ne sont pas vides.
Problèmes fréquents et solutions
| Résultat | Cause | Solution |
|---|---|---|
| 0 au lieu d’un nombre | Le critère ne correspond pas exactement aux cellules : faute de frappe, espaces en trop dans les données ou nombres stockés en texte. | Vérifiez l’orthographe, nettoyez les données avec SUPPRESPACE et convertissez le texte en nombres. |
| Résultat trop petit après recopie | La plage n’était pas figée : elle a glissé vers le bas en recopiant la formule. | Figez la plage avec $ ($C$2:$C$9) avant de recopier. |
| #NOM? | Critère texte sans guillemets, par exemple =NB.SI(C2:C9;Livrée), ou formule copiée d’un site anglais (COUNTIF). | Mettez le texte entre guillemets et utilisez le nom français NB.SI. |
| #VALEUR! | La plage pointe vers un autre classeur qui est fermé. | Ouvrez l’autre classeur ou copiez les données dans votre fichier. |
NB.SI, NB.SI.ENS, NB ou NBVAL ?
NB.SI accepte une seule condition. NB.SI.ENS accepte plusieurs couples plage + critère et ne compte que les lignes qui les remplissent toutes, par exemple les commandes livrées et supérieures à 500 €. NB compte les cellules qui contiennent des nombres, et NBVAL compte toutes les cellules non vides, sans condition.
Questions fréquentes
Pourquoi mon NB.SI renvoie 0 ?
Aucune cellule de la plage ne correspond exactement au critère. Cherchez une faute de frappe, des espaces en trop ou des nombres stockés en texte. Vérifiez aussi que la plage couvre la bonne colonne.
Comment compter les cellules qui contiennent un mot ?
Entourez le mot du caractère générique * : =NB.SI(A2:A100;"*facture*") compte toutes les cellules qui contiennent facture n’importe où dans le texte.
Comment trouver les doublons avec NB.SI ?
À côté de votre liste, tapez =NB.SI($A$2:$A$100;A2) et recopiez vers le bas. Tout résultat supérieur à 1 indique une valeur présente plusieurs fois.
NB.SI fait-il la différence entre majuscules et minuscules ?
Non. "livrée", "Livrée" et "LIVRÉE" sont comptés de la même façon.
Continuez à pratiquer
Les 10 exercices NB.SI, avec explications et suivi de progression.
Ouvrir les exercices NB.SI